Перестановка местами WORD в REAL

[Ivydy]

Здравствуйте. Имею следующее. TIA Portal V15, S7-1200 с коммуникационным модулем CM1241 (MASTER).
По RS485 общаюсь с датчиком виброскорости(SLAVE). С датчика получаю ряд данных в виде массива REAL, но проблема, что видятся они в неадекватном виде. Я так понимаю, что нужно поменять местами WORD в REAL, то есть AB CD --> CD AB. Функции SWAP не подходят, они переделывают по другому. Как можно это сделать ? Заранее спасибо.

[MaksimNT]

поменять местами WORD в REAL, то есть AB CD --> CD AB.

как то вот так на *.scl

FUNCTION_BLOCK "Word_RAEL"
TITLE = Bytes are re-ordered to construct a REAL
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
VAR_INPUT
wLWord { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Word; // byte to form real value 1 of 4
wHWord { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Word; // byte to form real value 2 of 4
END_VAR

VAR_OUTPUT
OUT { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Real; // Resulting value constructed from bytes
END_VAR

VAR
Value { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Real; // Reconstructed value
Raw { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} AT Value : DWord; // Raw value constructed from WORD
END_VAR


BEGIN
// ============================================================================
// Word_RAEL
// Программа перевода полученных 2 WORD --> REAL
//
// ===========================================================================

#Raw.%W0 := #wHWord;
#Raw.%W1 := #wLWord;
#OUT := #Value;

END_FUNCTION_BLOCK

[Ivydy]

поменять местами WORD в REAL, то есть AB CD --> CD AB.

как то вот так на *.scl

FUNCTION_BLOCK "Word_RAEL"
TITLE = Bytes are re-ordered to construct a REAL
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
VAR_INPUT
wLWord { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Word; // byte to form real value 1 of 4
wHWord { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Word; // byte to form real value 2 of 4
END_VAR

VAR_OUTPUT
OUT { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Real; // Resulting value constructed from bytes
END_VAR

VAR
Value { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} : Real; // Reconstructed value
Raw { ExternalAccessible := 'False'; ExternalVisible := 'False'; ExternalWritable := 'False'} AT Value : DWord; // Raw value constructed from WORD
END_VAR


BEGIN
// ============================================================================
// Word_RAEL
// Программа перевода полученных 2 WORD --> REAL
//
// ===========================================================================

#Raw.%W0 := #wHWord;
#Raw.%W1 := #wLWord;
#OUT := #Value;

END_FUNCTION_BLOCK

Как я понимаю, это программа в среде программирования STEP7, в TIA PORTAL V15 такое работать не будет

[MaksimNT]

как то вот так на *.scl

BEGIN
// ============================================================================
// Word_RAEL
// Программа перевода полученных 2 WORD --> REAL
//
// ===========================================================================

#Raw.%W0 := #wHWord;
#Raw.%W1 := #wLWord;
#OUT := #Value;

END_FUNCTION_BLOCK

Как я понимаю, это программа в среде программирования STEP7, в TIA PORTAL V15 такое работать не будет

Ниже скрин из TIA PORTAL V15

[petr2off]

TIA Portal - это оболочка, в которой работает и Step-7 и WinCС.

[MaksimNT]

в исходнике (swap_bytes_real.scl) был следующее



FUNCTION_BLOCK "swap_bytes_REAL"
TITLE = Bytes are re-ordered to construct a REAL
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
VAR_INPUT
Byte_1 { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} : Byte; // byte to form real value 1 of 4
Byte_2 { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} : Byte; // byte to form real value 2 of 4
Byte_3 { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} : Byte; // byte to form real value 3 of 4
Byte_4 { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} : Byte; // byte to form real value 4 of 4
END_VAR

VAR_OUTPUT
OUT { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} : Real; // Resulting value constructed from bytes
END_VAR

VAR
Value { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} : Real; // Reconstructed value
Raw { S7_HMI_Accessible := 'False'; S7_HMI_Visible := 'False'} AT Value : DWord; // Raw value constructed from BYTES
END_VAR


BEGIN
#Raw.%B0 := #Byte_4;
#Raw.%B1 := #Byte_3;
#Raw.%B2 := #Byte_2;
#Raw.%B3 := #Byte_1;
#OUT := #Value;
END_FUNCTION_BLOCK

[LexSL]

А если так (функция, не FB):
classic Step7:

Код: Выделить всё

FUNCTION SwapWords : REAL

VAR_INPUT
    Number : REAL;
END_VAR
    
VAR_TEMP
    // Temporary Variables
    tmpReal : REAL;
    tmpRealArray AT tmpReal : ARRAY [0..1] OF WORD;
    tmpWord : WORD;
END_VAR
    tmpReal := Number;

    tmpWord := tmpRealArray[1];
    tmpRealArray[1] := tmpRealArray[0];
    tmpRealArray[0] := tmpWord;
    

    SwapWords := tmpReal;
END_FUNCTION

TIA Portal:

Код: Выделить всё

FUNCTION "SwapWords" : Real
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
   VAR_INPUT 
      Number : Real;
   END_VAR

   VAR_TEMP 
      tmpReal : Real;
      tmpRealArray AT tmpReal : Array[0..1] of Word;
      tmpWord : Word;
   END_VAR


BEGIN
	#tmpReal := #Number;
	
	#tmpWord := #tmpRealArray[1];
	#tmpRealArray[1] := #tmpRealArray[0];
	#tmpRealArray[0] := #tmpWord;
	
	#SwapWords := #tmpReal;
END_FUNCTION

[Barsukovm]

в STL
Swap Bytes in Word: CAW: swaps LSB < - > MSB
Swap Words in DWord: CAD: swaps LSW < - > MSW